home *** CD-ROM | disk | FTP | other *** search
/ QRZ! Ham Radio 8 / QRZ Ham Radio Callsign Database - Volume 8.iso / pc / files / dsp / 96000tar.z / 96000tar / 96000 / appb / b143b.asm < prev    next >
Encoding:
Assembly Source File  |  1992-04-28  |  3.5 KB  |  151 lines
  1. ; This program was originally published in the Motorola DSP96002 Users Manual
  2. ; and is provided under a DISCLAIMER OF WARRANTY available from Motorola DSP
  3. ; Operation, 6501 William Cannon Drive West, Austin, Texas 78735-8598.  For
  4. ; more information, refer to the DSP96002 Users Manual, Appendix B, DSP
  5. ; Benchmarks.
  6. ;
  7. ; B.1.43.2    Integer Incremental Line Drawing Algorithm  
  8. ;This implementation of line drawing uses Bresenham's algorithm. This  algorithm uses only integer op-
  9. ;erations to generate the points.  
  10. ;  Bresenham Line Drawing Implementation 
  11. ; 
  12. ;  When entering subroutine, the registers must 
  13. ;  be set as follows: 
  14. ; 
  15. ;    d0 =          d4 = 
  16. ;    d1 =          d5 = 
  17. ;    d2 = x1       d6 = x0 
  18. ;    d3 = y1       d7 = y0 
  19. ; 
  20. ;  When entering a line drawing loop, the registers 
  21. ;  are set as follows: 
  22. ; 
  23. ;    d6 = x0 
  24. ;    d7 = y0 
  25. ;    d4 = dmajor 
  26. ;    d5 = n0 = dminor 
  27. ;    r0 = dmajor/2 
  28. ;    m0 = dmajor - 1 
  29.   org    p:$50 
  30. ; Calculate dx and dy 
  31. _line 
  32.   sub    d6,d2    d2.l,d4.l 
  33.   sub    d7,d3    d3.l,d5.l 
  34. ; Determine whether to increment x or y 
  35.   tst    d2       d2.l,d0.l 
  36.   neg    d2       iflt 
  37.   tst    d3       d3.l,d1.l 
  38.   neg    d3       iflt 
  39.   cmp    d3,d2 
  40.   jge    _inc_x 
  41. ; Increment y case 
  42. ; If dy is negative, switch endpoints and sign of dx and dy 
  43. _inc_y 
  44.   tst    d1 
  45.   tfr    d4,d6    iflt 
  46.   tfr    d5,d7    iflt 
  47.   neg    d1       iflt 
  48.   neg    d0       iflt 
  49.   tst    d0 
  50.   jlt    _set_y_xn 
  51.  
  52. ; Increment y, dx positive case 
  53. ; Set up registers 
  54. _set_y_xp 
  55.   lsr    d1       d1.l,d2.l 
  56.   dec    d2       d2.l,d4.l 
  57.   move            d1.l,r0 
  58.   move            d2.l,m0 
  59.   move            d0.l,n0 
  60.   move            d0.l,d5.l 
  61. ; Draw first point 
  62.   jsr   _draw_point 
  63. ; Draw additional points 
  64.   do    d4.l,_line_y_xp 
  65.   inc   d7       r0,d2.l 
  66.   add   d5,d2    (r0)+n0 
  67.   cmp   d4,d2 
  68.   inc   d6       ifge 
  69.   jsr   _draw_point 
  70. _line_y_xp 
  71.   rts 
  72. ; Increment y, dx negative case 
  73. ; Set up registers 
  74. _set_y_xn 
  75.   lsr    d1       d1.l,d2.l 
  76.   dec    d2       d2.l,d4.l 
  77.   neg    d0       d1.l,r0 
  78.   move            d2.l,m0 
  79.   move            d0.l,n0 
  80.   move            d0.l,d5.l 
  81. ; Draw first point 
  82.   jsr   _draw_point 
  83. ; Draw additional points 
  84.   do    d4.l,_line_y_xn 
  85.   inc   d7       r0,d2.l 
  86.   add   d5,d2    (r0)+n0 
  87.   cmp   d4,d2 
  88.   dec   d6       ifge 
  89.   jsr   _draw_point 
  90. _line_y_xn 
  91.   rts 
  92.  
  93. ; Increment x case 
  94. ; If dx is negative, switch endpoints and sign of dx and dy 
  95. _inc_x 
  96.   tst    d0 
  97.   jeq    _draw1 
  98.   tfr    d4,d6    iflt 
  99.   tfr    d5,d7    iflt 
  100.   neg    d0       iflt 
  101.   neg    d1       iflt 
  102.   tst    d1 
  103.   jlt    _set_x_yn 
  104. ; Increment x, dy positive case 
  105. ; Set up registers 
  106. _set_x_yp 
  107.   lsr    d0       d0.l,d2.l 
  108.   dec    d2       d2.l,d4.l 
  109.   move            d0.l,r0 
  110.   move            d2.l,m0 
  111.   move            d1.l,n0 
  112.   move            d1.l,d5.l 
  113. ; Draw first point 
  114.   jsr   _draw_point 
  115. ; Draw additional points 
  116.   do    d4.l,_line_x_yp 
  117.   inc   d6       r0,d2.l 
  118.   add   d5,d2    (r0)+n0 
  119.   cmp   d4,d2 
  120.   inc   d7       ifge 
  121.   jsr   _draw_point 
  122. _line_x_yp 
  123.   rts 
  124. ; Increment x, dy negative case 
  125. ; Set up registers 
  126. _set_x_yn 
  127.   lsr    d0       d0.l,d2.l 
  128.   dec    d2       d2.l,d4.l 
  129.   neg    d1       d0.l,r0 
  130.   move            d2.l,m0 
  131.   move            d1.l,n0 
  132.   move            d1.l,d5.l 
  133.  
  134. ; Draw first point 
  135.   jsr   _draw_point 
  136. ; Draw additional points 
  137.   do    d4.l,_line_x_yn 
  138.   inc   d6       r0,d2.l 
  139.   add   d5,d2    (r0)+n0 
  140.   cmp   d4,d2 
  141.   dec   d7       ifge 
  142. _draw1 
  143.   jsr   _draw_point 
  144. _line_x_yn 
  145.   rts 
  146. ; Draw a single point 
  147. _draw_point 
  148.   move           d6.l,x:(r1)+   d7.l,y: 
  149.   rts 
  150.  
  151.